**Web Appendix A**

**Acute-Effects CCREM**

A broad description of how to estimate this type of model with general purpose software is presented in the text, including data layout and model specification. In general, the data must be in a long format with repeated measurements for an individual having separate rows, and the value of the group variable based on which group a person is a member of at each point in time. We have made available a simulated dataset called “toy” based on the parameters described in simulation one, using 20% mobility and group variance=.10.

**PROC** **MIXED** data=toy covtest;

CLASS group person;

MODEL y = time x interaction / solution;

RANDOM intercept time /SUBJECT=person TYPE=un ;

RANDOM intercept / SUBJECT= group;

**RUN**;

The first statement indicates the MIXED procedure is being used and identifies the dataset. The CLASS statement indicates that group membership and person are each being treated as classification variables. The group variable identifies which group an individual belongs to at each point in time. Only a single group variable is needed if a CLASS statement is being used. In the MODEL statement the response is to the left of the equal sign and to the right are the covariates (intercept, “time”, “x”, and the time by x interaction labeled “interaction”). The fixed effect for the intercept is modeled implicitly by the program. The first RANDOM statement estimates random effects for intercept and time. The subject is the person, identified with SUBJECT=person, and a covariance between intercept and time is fit using TYPE=un. The second RANDOM statement is used to estimate the crossed random effect for the group variable. In contrast to the previous random statement however, the subject is group not the individual, as indicated by SUBJECT=group.

***SPSS***

MIXED

y BY group person WITH time x interaction

/FIXED = time x interaction

/RANDOM intercept time | SUBJECT(person) COVTYPE(un)

/RANDOM intercept | SUBJECT(group).

The first line identifies that the Mixed procedure is being used. The second line identifies the variable types. The first word is the name of the variable corresponding to the response. To the right of the BY statement is a list of the categorical variables (either random or fixed), which plays a similar role to the CLASS statement in SAS, here indicating that group membership (i.e., membership at each particular point in time) and individuals are each being treated as classification variables. To the right of the WITH statement is a list of the continuous covariates that will be modeled. In the FIXED statement the covariates that are being modeled are listed to the right of the equal sign. The fixed effect for time is apparent in the code, but as with SAS, SPSS implicitly models the intercept as well. Additional covariates could be included on this line as well. The first RANDOM statement estimates random effects for intercept and time. The subject is the person, identified with SUBJECT(id), and a covariance between intercept and time is fit using COVTYPE(UN). The second RANDOM statement estimates the crossed random effect for the group variable. Here, the subject is the group not the individual but rather the group, as indicated by SUBJECT(group).

***R***

Use of lmer requires installation of the lme4 package and loading of the library.

*Install.packages(“lme4”)*

*library (lme4)*

The model is then fit with the following programming statements:

*model<-lmer(y~ x+Time+Interaction+(Time|Person)+(1|Group), data=toy)*

*summary (model)*

In the first line, we output the results of the lmer program using “<-” and call it “model”. To the right of “<-” we initiate the lmer program with “lmer ()”. The response variable appears to the left of the tilde and the fixed and random effects to the right of the tilde separated by “+”. The fixed effect for the intercept is modeled automatically and a fixed effects for time, x, and their interaction are specified. The random effects are each specified inside a new set of parentheses. With the specification of “*(Time|Person)” ,* R includes a random effect for time, and automatically includes a random effect for the intercept, and allows for the two to covary.Here the subject is the person and is identified after the “|” with the variable Person. Next is the crossed random effect, identified as “*(1|Group)”.* The 1 indicates an intercept or constant is being used with the subject as the group. This is virtually identical to the programming statements used in SAS and SPSS. Lastly, “data=toy” identifies the data set being used and “summary(model)” prints out the results of the analysis.

**Cumulative-Effects CCREM and Multiple Membership Models Using SAS**

We begin by showing how PROC GLIMMIX can be used to estimate the acute-effect CCREMs fit earlier, in part because it is more flexible than PROC MIXED. For instance, GLIMMIX allows for a wide variety of response distributions (e.g., binomial, count). More relevant here is that GLIMMIX allows for estimation of cumulative-effects CCREM and multiple membership models. The PROC MIXED syntax for the acute-effects CCREM given above would apply to PROC GLIMMIX as well (simply substitute “GLIMMIX” for “MIXED”). First we show an alternate syntax specification, because it forms the foundation of the syntax approach for fitting cumulative-effects CCREM and multiple membership models. We first reformat the data in the “toy” dataset to produce a new dataset called “acute”:

**proc** **glimmix** data=toy outdesign(z)=zmat;

class group;

model y = ;

random group ;

**run**;

**data** acute ;

set zmat ;

array glimout \_z1-\_z10;

array recode x1-x10;

by person;

do i=**1** to **10**;

if glimout{i} > **0** then do; recode{i}=glimout{i}; recode{i}=i; end;

if glimout{i} = **0** then do; recode{i}=glimout{i}; end;

end;

drop i \_z1-\_z10;

**run**;

Then we fit the following model on the acute dataset:

**PROC** **GLIMMIX** data=acute;

CLASS x1-x10 person;

EFFECT group2 = multimember (x1-x10/details);

MODEL y = time x interaction;

RANDOM intercept time /SUBJECT=person TYPE=un;

RANDOM group2 ;

**RUN**;

In this dataset there are ten groups and each person in this example is present in only one group at a particular time, therefore x1-x10 represent membership in one of the ten groups at each point in time. The variables x1-x10 used here cannot be dummy coded however, rather values indicating group membership must be distinct from one variable to the next (e.g., x1: 1,0 x2: 2,0 x3: 3,0). SAS uses the number of distinct levels in x1-x10 to determine the number of columns to create in the constructed effect. The EFFECT statement with a multimember specification creates this constructed effect, which we have called group2 and treat as a random variable.Notably, specification of the cross-classified random effect as *RANDOM group2* is different from what was previously shown in PROC MIXED*.* This is because the created group2 effect cannot be used in the *SUBJECT=* portion of the syntax. Nevertheless, the programming statements lead to estimation of equivalent models. SAS uses information from both Random statements to create the random effects design matrix.

It is important to closely examine the random effects design matrix for the group effect from this example. This can be accomplished by adding *outdesign(z)=zmatN* to the first line of code in the last call to Proc Glimmix. If the following statement is commented out: *RANDOM intercept time /SUBJECT=person TYPE=un*, the number of distinct levels in the random effects design matrix (the \_Z1…\_Z11) for the group effect made from x1-x10 is eleven (0,1…10), therefore it will contain eleven columns/variables. The values assigned to entries in the design matrix correspond to the number of times a value appears for a particular person at a point in time in x1-x10. The values in the first column of the design matrix will correspond to the number of 0s in each row of x1-x10, which yields a value of 9 for all rows of the first column of the design matrix because each person is a member of only one group at a time. In the acute-effects model this column is a constant that does not contribute any additional information to the model beyond the other columns in the design matrix and therefore has no effect. The remaining ten variables will each contain only values of 1 or 0, which also follows from each person being present in only one group at a particular point in time.

Cumulative-effects CCREM and multiple membership models will require some additional data manipulation prior to their use in the GLIMMIX procedure:

**data** cumulative1;

set acute ;

array origvar x1-x10;

array carry a1-a10;

by person;

retain carry;

do i=**1** to **10**;

if first.person then carry{i} = **.** ;

end;

do i=**1** to **10**;

if origvar{i} > **0** then do;carry{i}=origvar{i};end;

end;

**run**;

**data** cumulative2;

set cumulative1;

array origvar x1-x10;

array carry a1-a10;

do i=**1** to **10**;

if origvar{i} = **.** then carry{i} = **.** ;

if origvar{i} = **0** and carry{i} = **.** then carry{i}=**0** ;

end;

**run**;

**data** cumulative3 ;

set cumulative2;

array carry a1-a10;

array weight w1-w10;

do i=**1** to **10**;

if carry{i}>**0** then weight{i}=**1**;else weight{i}=carry{i};

end;

drop i;

**run**;

Then we fit the following model on the cumulative3 dataset:

**PROC** **GLIMMIX** data= cumulative3;

CLASS a1-a10 person;

EFFECT group2 = multimember (a1-a10/ weight=(w1-w10) details);

MODEL y = time x interaction;

RANDOM intercept time /SUBJECT=person TYPE=un;

RANDOM group2 ;

**RUN**;

The grouping variables a1-a10 are based on the x1-x10 grouping variables that were previously described for the acute effects model, but for each person all previous group memberships are carried forward in time. Therefore, a1-a10 can have more than one nonzero entry per row. Unfortunately, it is not as simple as using a1-a10 in place of x1-x10 to fit a cumulative effects model because the number of 0s in the first column is no longer constant. Therefore, it is necessary to use weights as dummy codes to activate observations in all columns but the first one, which is the primary goal of using weights here. However, if we include the *stdize* option (place it before the *details* option in the syntax*)*, this will impose the constraint that multiple group memberships for a single person-time record will be weighed equally and sum to a value of 1, giving us the model in (7).

Notably, the SAS documentation illustrates a seemingly simpler approach that could be used to fit these cumulative effect CCREM and multiple membership models in their example of students nested in multiple teachers. The approach adapted to a longitudinal context would involve creating as many grouping variable as there are time points in the study and the cell values for each of these grouping variables would consist of group membership identifications for each person. However, this approach will not work in a longitudinal context with random subject effects due to a coding bug. The bug causes a record to be recorded as missing if a person is not simultaneously a member of all groups. In correspondence with technical support staff at SAS this bug should be corrected in later versions of the software.

**Acute-Effects CCREM with Dynamic Group Effects Using SAS**

An acute-effects CCREM with dynamic group effects consists of the same programming statements as a stable group model, except we slightly modify the RANDOM statement specifying the cross classification with group. The modification consists of identifying a time variable that is also listed in a CLASS statement and indicating the form of the covariance matrix (e.g., unstructured, compound symmetry, etc.). First we need to make a dataset where a second time variable is created ‘time2’ with identical values to the variable ‘time’.

**data** toy2;

set toy;

time2=time;

**run**;

In proc mixed we use the “time” to specify continuous fixed effect, but “time2” to specify a classification variable that can be used to structure the covariance matrix (here we use a first-order autoregressive structure). Keep in mind however that data generation process for this example did not allow for the group effects to change over time, therefore it is not surprising that correlation among the rho parameter is close to 1.

**PROC** **MIXED** data=toy2 covtest;

CLASS group person time2;

MODEL y = time x interaction / solution;

RANDOM intercept time /SUBJECT=person TYPE=un ;

RANDOM time2 / SUBJECT= group TYPE=ar(1);

**RUN**;

**Example 1**

The dataset for this example is available as part of the online material. The variables consist of:

childid- a child identification variable

schoolidccrem- a school identification variable that can change for each child in each point in time

math-math achievement score

year- year in school (kindergarten, 1st, 3rd, 5th grade)

year2- year in school (kindergarten, 1st, 3rd, 5th grade)

gender- male (1) or female (2)

schooltype- public (1) private (0)

Given the large size of the data we use HPMIXED whenever possible to increase the speed with which models are fit (this procedure has a more limited number of covariance structures available for the random effects than MIXED). We start off by fitting an acute-effects CCREM that has stable group effects over time:

**PROC** **HPMIXED** data=data3;

CLASS childid schoolidccrem ;

MODEL math= year gender schooltype gender\*year/s;

RANDOM intercept year/sub=childid TYPE=un;

RANDOM intercept /sub=schoolidccrem;

**RUN**;

Acute-effects CCREM with dynamic group effects (unstructured covariance matrix):

**PROC** **HPMIXED** data=data3;

CLASS childid schoolidccrem year2;

MODEL math= year gender schooltype gender\*year/s;

RANDOM intercept year/sub=childid TYPE=un;

RANDOM year2 /sub=schoolidccrem TYPE=un;

**RUN**;

Using the estimated covariance matrix that is outputted from the unstructured model to calculate the correlation of the group effects over time:

**data** covs;

input t1 t2 t3 t4;

datalines;

17.3132 23.7342 12.0855 8.9422

23.7342 81.4858 53.3208 26.3796

12.0855 53.3208 56.7376 40.8660

8.9422 26.3796 40.8660 45.7929

;

**run**;

**proc** **iml**;

use covs;

read all var{t1 t2 t3 t4} into cov ;

print cov;

corr = inv(sqrt(diag(cov)))\*cov\*inv(sqrt(diag(cov)));

print corr;

**run**;

**quit**;

Acute-effects CCREM with dynamic group effects (compound symmetry covariance matrix):

**PROC** **HPMIXED** data=data3;

CLASS childid schoolidccrem year2;

MODEL math= year gender schooltype gender\*year/s;

RANDOM intercept year/sub=childid TYPE=un;

RANDOM year2 /sub=schoolidccrem TYPE=cs;

**RUN**;

Acute-effects CCREM with dynamic group effects (spatial power covariance matrix). This covariance structure is not available in HPMIXED therefore we use MIXED. The NOCLPRINT, DDFM=BW, and notest options are used to increase the speed with which this model is fit:

**PROC** **MIXED** data=data3 NOCLPRINT;

CLASS childid schoolidccrem year2;

MODEL math= year gender schooltype gender\*year/s DDFM=BW notest;

RANDOM intercept year/sub= childid type=un;

RANDOM year2 /sub=schoolidccrem type=sp(pow)(year);

**run**;

Below is a macro for creating a dataset with the formatting necessary to fit a cumulative-effects CCREM. The macro input parameters are as follows:

datain = *input dataset name*

personID=*id variable name used to identify distinct people*

grpname=*id variable name used to identify distinct groups*

outcome= *the outcome variable name*

dataout=*the name of the dataset you want to be created*

**%macro** cummulativeformat(datain=, personID=, grpname=,outcome=, dataout=);

proc freq data=&datain;

tables &grpname/out=w;

run;

ods output summary=group;

proc means data=w n;

var &grpname;

run;

data group2;

set group;

call symput("groupN", trim(left(put(&grpname.\_N,best.)))) ;\*&grpname;

run;

%put groupN ===========> |&groupN| ;

proc glimmix data=&datain outdesign(z)=zmat;

class &grpname;

model &outcome = ;

random &grpname ;

run;

proc sort data=zmat;

by &personID;

run;

data acute ;

set zmat ;

array glimout \_z1-\_z&groupN;

array recode x1-x&groupN;

by &personID;

do i=**1** to &groupN;

if glimout{i} > **0** then do; recode{i}=glimout{i}; recode{i}=i; end;

if glimout{i} = **0** then do; recode{i}=glimout{i}; end;

end;

drop i \_z1-\_z&groupN;

run;

data cumulative1 ;

set acute ;

array origvar x1-x&groupN;

array carry a1-a&groupN;

by &personID;

retain carry;

do i=**1** to &groupN;

if first.&personID then carry{i} = **.** ;

end;

do i=**1** to &groupN;

if origvar{i} > **0** then do;carry{i}=origvar{i};end;

end;

run;

data cumulative2;

set cumulative1;

array origvar x1-x&groupN;

array carry a1-a&groupN;

do i=**1** to &groupN;

if origvar{i} = **.** then carry{i} = **.** ;

if origvar{i} = **0** and carry{i} = **.** then carry{i}=**0** ;

end;

run;

data &dataout ;

set cumulative2;

array carry a1-a&groupN;

array weight w1-w&groupN;

do i=**1** to &groupN;

if carry{i}>**0** then weight{i}=**1**;else weight{i}=carry{i};

end;

drop i;

run;

**%mend**;

%***cummulativeformat***(datain=data3,personID=childid, grpname=schoolidccrem, outcome=math, dataout=data4);

Fitting Model (19):

**PROC** **GLIMMIX** data=data4;

CLASS a1-a245 childid year2;

EFFECT group2 = multimember (a1-a245/ weight=(w1-w245) details);

MODEL math= year gender schooltype gender\*year;

RANDOM intercept year /SUBJECT=childid TYPE=un ;

RANDOM group2/;

**RUN**;

Fitting Model (20):

**PROC** **GLIMMIX** data=data4;

CLASS a1-a245 childid year2;

EFFECT group2 = multimember (a1-a245/ weight=(w1-w245) stdize details);

MODEL math= year gender schooltype gender\*year;

RANDOM intercept year /SUBJECT=childid TYPE=un ;

RANDOM group2/;

**RUN**;

**Example 2**

The data elements consist of:

id - clinician identification variable

supervisor\_ - a group identification variable based on who is the supervisor of that group, which can change for each clinician in each point in time

ebpas\_-evidence based practice score

clin\_time- year since clinician enrolled in study (0, .5, 1, 1.5) coded as 0,1,2,3

implement\_time- year since study started (0, .5, 1, 1.5) coded as 0,1,2,3

monitoring\_- yes (1) or no (0)

ebstatus\_- yes (1) or no (0)

Acute-effects CCREM with stable group effects:

**PROC** **HPMIXED** data=ex2;

CLASS id supervisor\_ implement\_time;

MODEL ebpas\_ = clin\_time ebstatus\_ ebstatus\_\*clin\_time monitoring\_ monitoring\_\*clin\_time ebstatus\_\*clin\_time\*monitoring\_ ebstatus\_\*monitoring\_/SOLUTION;

RANDOM intercept clin\_time /sub=id TYPE=un ;

RANDOM intercept/ sub=supervisor\_;

**RUN**;

Acute-effects CCREM with dynamic group effects (unstructured covariance matrix):

**PROC** **HPMIXED** data= ex2;

CLASS id supervisor\_ implement\_time;

MODEL ebpas\_ = clin\_time ebstatus\_ ebstatus\_\*clin\_time monitoring\_ monitoring\_\*clin\_time ebstatus\_\*clin\_time\*monitoring\_ ebstatus\_\*monitoring\_/SOLUTION;

RANDOM intercept clin\_time /sub=id TYPE=un ;

RANDOM implement\_time/ sub=supervisor\_ TYPE=un;

**RUN**;

Acute-effects CCREM with dynamic group effects (compound symmetry covariance matrix):

**PROC** **HPMIXED** data= ex2;

CLASS id supervisor\_ implement\_time;

MODEL ebpas\_ = clin\_time ebstatus\_ ebstatus\_\*clin\_time monitoring\_ monitoring\_\*clin\_time ebstatus\_\*clin\_time\*monitoring\_ ebstatus\_\*monitoring\_/SOLUTION;

RANDOM intercept clin\_time /sub=id TYPE=un ;

RANDOM implement\_time/ sub=supervisor\_ TYPE=cs;

**RUN**;

Acute-effects CCREM with dynamic group effects (first-order autoregressive covariance matrix):

**PROC** **HPMIXED** data= ex2;

CLASS id supervisor\_ implement\_time;

MODEL ebpas\_ = clin\_time ebstatus\_ ebstatus\_\*clin\_time monitoring\_ monitoring\_\*clin\_time ebstatus\_\*clin\_time\*monitoring\_ ebstatus\_\*monitoring\_/SOLUTION;

RANDOM intercept clin\_time /sub=id TYPE=un ;

RANDOM implement\_time/ sub=supervisor\_ Type=ar(**1**);

**run**;

Acute-effects CCREM with dynamic group effects (toeplitzcovariance matrix):

**PROC** **MIXED** data= ex2;

CLASS id supervisor\_ implement\_time;

MODEL ebpas\_ = clin\_time ebstatus\_ ebstatus\_\*clin\_time monitoring\_ monitoring\_\*clin\_time ebstatus\_\*clin\_time\*monitoring\_ ebstatus\_\*monitoring\_/SOLUTION;

RANDOM intercept clin\_time /sub=id TYPE=un ;

RANDOM implement\_time/ sub=supervisor\_ type=toep;

**RUN**;

Acute-effects CCREM with dynamic group effects (stable banded lag 2covariance matrix). This macro is from Bauer et al (2013), please consult that paper for more details about implementing this covariance matrix:

**%macro** stableband(lag=,Gtimes=);

data sb;

do p = **1** to &lag. + **1**;

do i = **1** to &Gtimes.;

array col[&Gtimes.] col1-col&Gtimes.;

do j = **1** to &Gtimes.;

parm = p;

row = i;

if p < &lag. + **1** then do;

if (i-j) = p-**1** then col[j] = **1**; else col[j]=**0**;

end;

else do;

if j <= i - &lag. then col[j] = **1**; else col[j]=**0**;

end;

end;

output;

end;

end;

drop j i p;

run;

**%mend**;

%***stableband***(lag=**2**,Gtimes=**4**);

**PROC** **MIXED** data= ex2;

CLASS id supervisor\_ implement\_time;

MODEL ebpas\_ = clin\_time ebstatus\_ ebstatus\_\*clin\_time monitoring\_ monitoring\_\*clin\_time ebstatus\_\*clin\_time\*monitoring\_ ebstatus\_\*monitoring\_/SOLUTION;

RANDOM intercept clin\_time /sub=id TYPE=un ;

RANDOM implement\_time/ sub=supervisor\_ TYPE=lin(**3**) ldata=sb;

PARMS (**.122**) (-**.005**) (**.014**) (**.006**) (**.001**) (**.001**) (**.001**) /;

**RUN**;

%***cummulativeformat***(datain= ex2, personID=id, grpname=supervisor\_, outcome=ebpas\_, dataout= ex2\_2);

Fitting Model (22):

**PROC** **GLIMMIX** data= ex2\_2;

CLASS a1-a33 id supervisor\_ implement\_time;

EFFECT group2 = multimember (a1-a33/ weight=(w1-w33) details);

MODEL ebpas\_ = clin\_time ebstatus\_ ebstatus\_\*clin\_time monitoring\_ monitoring\_\*clin\_time ebstatus\_\*clin\_time\*monitoring\_ ebstatus\_\*monitoring\_/SOLUTION;

RANDOM intercept clin\_time /sub=id TYPE=un ;

RANDOM group2/;

**RUN**;

Fitting Model (23):

**PROC** **GLIMMIX** data= ex2\_2;

CLASS a1-a33 id supervisor\_ implement\_time;

EFFECT group2 = multimember (a1-a33/ weight=(w1-w33) stdize details);

MODEL ebpas\_ = clin\_time ebstatus\_ ebstatus\_\*clin\_time monitoring\_ monitoring\_\*clin\_time ebstatus\_\*clin\_time\*monitoring\_ ebstatus\_\*monitoring\_/SOLUTION;

RANDOM intercept clin\_time /sub=id TYPE=un ;

RANDOM group2/;

**RUN**;

**Web Appendix B**

***Simulation 1 Detailed Results***

Generally, we see that the acute-effects CCREM (the correctly specified model) has less bias and greater accuracy in estimating the random parameters of the model than the incorrectly specified nested model (Table 1). This is most noticeable for the group variance, where the incorrectly specified nested model tends to underestimate this quantity across all conditions of the simulation. There is also a positive bias in the slope and residual variances and negative bias in the covariance for the incorrectly specified nested model in many conditions of the simulation. Lastly, there is a tendency in the incorrectly specified nested model for the standard errors of the time by treatment interaction to be overestimated, but this is more noticeable when the group variance is larger.

We note that the acute-effects CCREM can confer a bias and lead to inaccuracy for some parameters (person-level intercept, and covariance) when both the number of clusters and sample size within cluster are small. Importantly though, the degree to which this happens is equivalent to when the data generation process is based on a nested model and a nested model is fit. Therefore, there shouldn’t be any reservations associated with fitting and acute-effect CCREM beyond fitting a nested model. With 5% and 35% group mobility the pattern parallels that presented here (see Tables 2 & 3), but with lesser and greater magnitude, respectively.

***Simulation 2 Detailed Results***

The results presented in Table 4 suggest that the findings parallel thoseof study one. The dynamic group AR model (correctly specified model) has less bias and greater accuracy in estimating the random parameters of the model than the stable group model (incorrectly specified model). For the group variance, the stable group model tends to underestimate this quantity across all conditions of the simulation. There is also a positive bias in the slope and residual variances and negative bias in the covariance for the stable group model in many conditions of the simulation, with the bias largest in the high group variance conditions. We did not find any effect on the standard errors of the time by treatment interaction. As in study 1, the dynamic group model can confer a bias and lead to inaccuracy for some parameters (person-level intercept, covariance, group-time correlation () when both the number of clusters and sample size within cluster are small, but such a model may still be preferable to a stable group model if we consider the comparative magnitude of the errors. Results for the first-order autoregressive structure with heterogeneous variances are presented in Table 5. The results are largely consistent with those already reported, although the magnitude of the group variance relative bias is larger.

***Simulation 3 Detailed Results***

The resultsin Table 6suggest that the acute-effects dynamic group AR model (correctly specified model) generally has less bias and greater accuracy in estimating the random parameters of the model than the nested stable group model (incorrectly specified model). The pattern is similar to that observed in studies one and two, for instance, the nested stable group model tends to underestimate the group variance and overestimate the slope and residual variances across all conditions of the simulation. It should be noted that unlike studies one and two, the group variance is estimated with less accuracy in the correctly specified model vs. incorrectly specified model, unless the number of clusters is 30 or more and cluster size is 15 or more. Moreover, the results suggest that the magnitudes of the errors in the incorrectly specified model are enhanced by misspecification of *both* time-varying group membership and group effects. As in study one, there is a tendency in the incorrectly specified nested model for the standard errors of the time by treatment interaction to be overestimated in the larger variance conditions. Also similar to the previous two studies the acute-effects dynamic group AR model does have a bias (person-level intercept, covariance, group-time correlation) when both the number of clusters and sample size within cluster are small, but such a model is still appears preferable to the nested stable group model.

Table 1. Results for Simulation One with 20% Mobility and Between Group Variance of .1 or .2

|  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- |
|  |  | | | | | | | |  | | | | | | | |
| Groups  (n per group) | 10 (5) | | 10 (15) | | 30 (5) | | 30 (15) | | 10 (5) | | 10 (15) | | 30 (5) | | 30 (15) | |
| *Acute CCREM*  *(Correct Model)* | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS |
| Group variance, | 0 | 0.12 | -2 | 0.10 | 2 | 0.06 | -1 | 0.06 | 4 | 0.07 | 1 | 0.05 | -3 | 0.04 | 0 | 0.03 |
| Residual variance, | -2 | 0.05 | 0 | 0.03 | -1 | 0.03 | 0 | 0.02 | -2 | 0.05 | 0 | 0.03 | -1 | 0.03 | 0 | 0.02 |
| Intercept variance, | 18 | 0.08 | 1 | 0.05 | 5 | 0.05 | 1 | 0.03 | 16 | 0.08 | 3 | 0.05 | 4 | 0.05 | -1 | 0.03 |
| Covariance, | -30 | 0.04 | -3 | 0.02 | -5 | 0.02 | -3 | 0.01 | -31 | 0.03 | -5 | 0.02 | -6 | 0.02 | 3 | 0.01 |
| Slope variance, | 7 | 0.03 | 1 | 0.02 | 0 | 0.02 | 1 | 0.01 | 9 | 0.03 | 1 | 0.02 | 1 | 0.02 | -1 | 0.01 |
| SE (Treat\*Time),SE () | -1 |  | 1 |  | 0 |  | 2 |  | -2 |  | -2 |  | -2 |  | 0 |  |
| *Nested*  *(Incorrect Model)* |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| Group variance, | -29 | 0.12 | -28 | 0.10 | -24 | 0.08 | -26 | 0.07 | -26 | 0.07 | -27 | 0.05 | -29 | 0.05 | -26 | 0.04 |
| Residual variance, | 7 | 0.07 | 9 | 0.05 | 8 | 0.05 | 8 | 0.04 | 3 | 0.06 | 4 | 0.04 | 3 | 0.04 | 4 | 0.03 |
| Intercept variance, | 24 | 0.09 | -3 | 0.05 | 9 | 0.06 | -3 | 0.03 | 21 | 0.09 | 2 | 0.05 | 9 | 0.05 | -1 | 0.03 |
| Covariance, | -52 | 0.04 | 2 | 0.02 | -24 | 0.03 | 2 | 0.01 | -50 | 0.04 | -7 | 0.02 | -23 | 0.02 | 0 | 0.01 |
| Slope variance, | 37 | 0.04 | 30 | 0.03 | 30 | 0.02 | 31 | 0.02 | 25 | 0.03 | 16 | 0.02 | 15 | 0.02 | 15 | 0.01 |
| SE (Treat\*Time),SE () | 6 |  | 9 |  | 6 |  | 10 |  | 1 |  | 1 |  | 1 |  | 3 |  |
| *Nested*  *(Reference Model)* |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| Group variance, | -1 | 0.12 | -2 | 0.10 | 2 | 0.07 | -1 | 0.06 | 3 | 0.08 | 1 | 0.05 | -3 | 0.04 | 0 | 0.03 |
| Residual variance, | -2 | 0.05 | 0 | 0.03 | -1 | 0.03 | 0 | 0.02 | -2 | 0.05 | 0 | 0.03 | -1 | 0.03 | 0 | 0.02 |
| Intercept variance, | 17 | 0.08 | 2 | 0.05 | 5 | 0.05 | 1 | 0.03 | 16 | 0.08 | 2 | 0.05 | 4 | 0.05 | -1 | 0.03 |
| Covariance, | -28 | 0.04 | -5 | 0.02 | -5 | 0.02 | -3 | 0.01 | -33 | 0.03 | -5 | 0.02 | -6 | 0.02 | 3 | 0.01 |
| Slope variance, | 6 | 0.03 | 2 | 0.02 | 1 | 0.02 | 1 | 0.01 | 10 | 0.03 | 1 | 0.02 | 1 | 0.02 | -1 | 0.01 |
| SE (Treat\*Time),SE () | -1 |  | 1 |  | 0 |  | 2 |  | -1 |  | -2 |  | -2 |  | 0 |  |

Table 2. Results from Simulation One with 5% Mobility

|  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- |
|  |  | | | | | | | |  | | | | | | | |
| Groups  (n per group) | 10 (5) | | 10 (15) | | 30 (5) | | 30 (15) | | 10 (5) | | 10 (15) | | 30 (5) | | 30 (15) | |
|  | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS |
| *Acute CCREM*  *(Correct Model)* |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| Group | 3 | 0.13 | -2 | 0.10 | -2 | 0.07 | 1 | 0.06 | -2 | 0.08 | 2 | 0.06 | 2 | 0.04 | -1 | 0.03 |
| Residual | -2 | 0.05 | 0 | 0.03 | -1 | 0.03 | 0 | 0.02 | -1 | 0.05 | -1 | 0.03 | -1 | 0.03 | 0 | 0.02 |
| Intercept | 18 | 0.08 | 3 | 0.05 | 3 | 0.05 | -1 | 0.03 | 20 | 0.08 | 3 | 0.05 | 4 | 0.05 | 1 | 0.03 |
| Covariance | -32 | 0.03 | -7 | 0.02 | -6 | 0.02 | 2 | 0.01 | -34 | 0.04 | -10 | 0.02 | -6 | 0.02 | 0 | 0.01 |
| Slope | 5 | 0.03 | 3 | 0.02 | 2 | 0.02 | -1 | 0.01 | 9 | 0.03 | 2 | 0.02 | 1 | 0.02 | 0 | 0.01 |
| SE Treat\*Time | -2 | 0.00 | -1 | 0.00 | 1 | 0.00 | -4 | 0.00 | 0 | 0.00 | -1 | 0.00 | 0 | 0.00 | -2 | 0.00 |
| *Nested*  *(Incorrect Model)* |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| Group | -5 | 0.13 | -10 | 0.10 | -9 | 0.07 | -7 | 0.06 | -9 | 0.07 | -7 | 0.05 | -6 | 0.04 | -8 | 0.03 |
| Residual | 1 | 0.06 | 2 | 0.03 | 1 | 0.03 | 2 | 0.02 | 0 | 0.05 | 0 | 0.03 | 0 | 0.03 | 1 | 0.02 |
| Intercept | 18 | 0.08 | 2 | 0.05 | 4 | 0.05 | -2 | 0.03 | 21 | 0.09 | 3 | 0.05 | 5 | 0.05 | 1 | 0.03 |
| Covariance | -34 | 0.03 | -3 | 0.02 | -11 | 0.02 | 6 | 0.01 | -37 | 0.04 | -9 | 0.02 | -11 | 0.02 | 0 | 0.01 |
| Slope | 15 | 0.03 | 12 | 0.02 | 12 | 0.02 | 9 | 0.01 | 13 | 0.03 | 7 | 0.02 | 6 | 0.02 | 4 | 0.01 |
| SE Treat\*Time | 0 | 0.00 | 1 | 0.00 | 3 | 0.00 | -2 | 0.00 | 0 | 0.00 | 0 | 0.00 | 1 | 0.00 | -1 | 0.00 |
| *Nested*  *(Reference Model)* |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| Group | 3 | 0.13 | -2 | 0.10 | -3 | 0.07 | 0 | 0.06 | -1 | 0.08 | 1 | 0.06 | 1 | 0.05 | -1 | 0.03 |
| Residual | -2 | 0.05 | 0 | 0.03 | -1 | 0.03 | 0 | 0.02 | -1 | 0.05 | -1 | 0.03 | -1 | 0.03 | 0 | 0.02 |
| Intercept | 17 | 0.08 | 3 | 0.05 | 3 | 0.05 | -1 | 0.03 | 20 | 0.08 | 3 | 0.05 | 3 | 0.05 | 1 | 0.03 |
| Covariance | -32 | 0.03 | -7 | 0.02 | -7 | 0.02 | 3 | 0.01 | -33 | 0.04 | -10 | 0.02 | -6 | 0.02 | 0 | 0.01 |
| Slope | 5 | 0.03 | 3 | 0.02 | 3 | 0.02 | -1 | 0.01 | 9 | 0.03 | 2 | 0.02 | 1 | 0.02 | 0 | 0.01 |
| SE Treat\*Time | -1 | 0.00 | -1 | 0.00 | 1 | 0.00 | -4 | 0.00 | 0 | 0.00 | -1 | 0.00 | 0 | 0.00 | -2 | 0.00 |

Table 3. Results from Simulation One with 35% Mobility

|  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- |
|  |  | | | | | | | |  | | | | | | | |
| Groups  (n per group) | 10 (5) | | 10 (15) | | 30 (5) | | 30 (15) | | 10 (5) | | 10 (15) | | 30 (5) | | 30 (15) | |
|  | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMS | %  Bias | RMSE |
| *Acute CCREM*  *(Correct Model)* |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| Group | 1 | 0.13 | -1 | 0.10 | 1 | 0.07 | 1 | 0.06 | -2 | 0.08 | -2 | 0.06 | -3 | 0.04 | 2 | 0.03 |
| Residual | -2 | 0.05 | -1 | 0.03 | -1 | 0.03 | 0 | 0.02 | -2 | 0.05 | 0 | 0.03 | 0 | 0.03 | 0 | 0.02 |
| Intercept | 20 | 0.08 | 6 | 0.05 | 4 | 0.05 | 0 | 0.03 | 14 | 0.08 | 2 | 0.05 | 3 | 0.05 | -1 | 0.03 |
| Covariance | -39 | 0.03 | -10 | 0.02 | -7 | 0.02 | 2 | 0.01 | -30 | 0.04 | -3 | 0.02 | -5 | 0.02 | 1 | 0.01 |
| Slope | 11 | 0.03 | 2 | 0.02 | 3 | 0.02 | 0 | 0.01 | 9 | 0.03 | 1 | 0.02 | 1 | 0.02 | -1 | 0.01 |
| SE Treat\*Time | 4 |  | -1 |  | -1 |  | -1 |  | -1 |  | -2 |  | -4 |  | 4 |  |
| *Nested*  *(Incorrect Model)* |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| Group | -44 | 0.13 | -44 | 0.10 | -43 | 0.07 | -39 | 0.06 | -44 | 0.07 | -44 | 0.05 | -44 | 0.04 | -40 | 0.03 |
| Residual | 15 | 0.06 | 15 | 0.03 | 16 | 0.03 | 16 | 0.02 | 6 | 0.05 | 8 | 0.03 | 8 | 0.03 | 8 | 0.02 |
| Intercept | 25 | 0.08 | -2 | 0.05 | 9 | 0.05 | -9 | 0.03 | 18 | 0.09 | 1 | 0.05 | 9 | 0.05 | -2 | 0.03 |
| Covariance | -69 | 0.03 | -8 | 0.02 | -40 | 0.02 | 4 | 0.01 | -53 | 0.04 | -9 | 0.02 | -31 | 0.02 | -6 | 0.01 |
| Slope | 48 | 0.03 | 39 | 0.02 | 42 | 0.02 | 40 | 0.01 | 25 | 0.03 | 20 | 0.02 | 19 | 0.02 | 20 | 0.01 |
| SE Treat\*Time | 13 |  | 9 |  | 9 |  | 10 |  | 3 |  | 3 |  | 0 |  | 10 |  |
| *Nested*  *(Reference Model)* |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |  |
| Group | 0 | 0.13 | -1 | 0.10 | 1 | 0.07 | 9 | 0.06 | -2 | 0.08 | -2 | 0.06 | -2 | 0.05 | 1 | 0.03 |
| Residual | -2 | 0.05 | -1 | 0.03 | -1 | 0.03 | 7 | 0.02 | -2 | 0.05 | 0 | 0.03 | 0 | 0.03 | 0 | 0.02 |
| Intercept | 20 | 0.08 | 5 | 0.05 | 3 | 0.05 | 3 | 0.03 | 14 | 0.08 | 2 | 0.05 | 3 | 0.05 | -1 | 0.03 |
| Covariance | -37 | 0.03 | -9 | 0.02 | -5 | 0.02 | 2 | 0.01 | -27 | 0.04 | -2 | 0.02 | -4 | 0.02 | 1 | 0.01 |
| Slope | 10 | 0.03 | 2 | 0.02 | 2 | 0.02 | 2 | 0.01 | 8 | 0.03 | 1 | 0.02 | 1 | 0.02 | -1 | 0.01 |
| SE Treat\*Time | 6 |  | -1 |  | -1 |  | -1 |  | -1 |  | -1 |  | -3 |  | 4 |  |

Table 4. Results for Simulation Two with a First-Order Autoregressive Population Covariance Structure

|  |  |  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- |
|  | 10 (5) | | 10 (15) | | 30 (5) | | 30 (15) | | 50 (50) | |
|  | %Bias | RMS | %Bias | RMS | %Bias | RMS | %Bias | RMS | %Bias | RMS |
| *Dynamic Group (AR)* | | | | | | | | | | |
| Group variance, | -7 | 0.11 | 0 | 0.09 | 0 | 0.06 | 0 | 0.05 | -1 | 0.03 |
| Residual variance, | -3 | 0.06 | -1 | 0.03 | -1 | 0.03 | 0 | 0.02 | 0 | 0.01 |
| Intercept variance, | 25 | 0.09 | 4 | 0.05 | 5 | 0.05 | 0 | 0.03 | 0 | 0.01 |
| Covariance, | -26 | 0.03 | -9 | 0.02 | -13 | 0.02 | 0 | 0.01 | 0 | 0.01 |
| Slope variance, | 8 | 0.03 | 2 | 0.02 | 5 | 0.02 | 0 | 0.01 | 1 | 0.00 |
| Group Time Correlation | -23 | 0.45 | -6 | 0.18 | -1 | 0.12 | -2 | 0.07 | -1 | 0.04 |
| SE (Treat\*Time),SE () | 0 |  | -4 |  | 3 |  | -3 |  | -3 |  |
| *Stable Group* |  |  |  |  |  |  |  |  |  |  |
| Group variance, | -21 | 0.11 | -17 | 0.10 | -16 | 0.07 | -16 | 0.06 | -16 | 0.05 |
| Residual variance, | 7 | 0.06 | 8 | 0.05 | 8 | 0.05 | 9 | 0.04 | 9 | 0.04 |
| Intercept variance, | 12 | 0.09 | -7 | 0.05 | 0 | 0.06 | -10 | 0.03 | -12 | 0.02 |
| Covariance, | -62 | 0.04 | -35 | 0.03 | -53 | 0.03 | -30 | 0.02 | -24 | 0.01 |
| Slope variance, | 32 | 0.04 | 28 | 0.02 | 31 | 0.02 | 29 | 0.02 | 30 | 0.02 |
| SE (Treat\*Time),SE () | 3 |  | 1 |  | 6 |  | 3 |  | 3 |  |
| *Dynamic Group (AR)* | | | | | | | | | | |
| Group variance, | -8 | 0.08 | -1 | 0.05 | -4 | 0.04 | 0 | 0.03 | 0 | 0.02 |
| Residual variance, | -4 | 0.06 | -1 | 0.03 | -1 | 0.03 | 0 | 0.02 | 0 | 0.01 |
| Intercept variance, | 34 | 0.10 | 3 | 0.05 | 9 | 0.05 | 0 | 0.03 | -1 | 0.01 |
| Covariance, | -36 | 0.04 | -8 | 0.02 | -12 | 0.02 | 1 | 0.01 | 1 | 0.01 |
| Slope variance, | 12 | 0.03 | 2 | 0.02 | 3 | 0.02 | 0 | 0.01 | 0 | 0.00 |
| Group Time Correlation, | -48 | 0.67 | -9 | 0.25 | -14 | 0.35 | -1 | 0.09 | -1 | 0.05 |
| SE (Treat\*Time),SE () | -2 |  | -1 |  | -4 |  | -6 |  | 1 |  |
| *Stable Group* |  |  |  |  |  |  |  |  |  |  |
| Group variance, | -17 | 0.07 | -18 | 0.05 | -19 | 0.04 | -16 | 0.03 | -16 | 0.02 |
| Residual variance, | 2 | 0.05 | 4 | 0.04 | 4 | 0.04 | 4 | 0.03 | 4 | 0.02 |
| Intercept variance, | 18 | 0.08 | -2 | 0.05 | 5 | 0.05 | -4 | 0.03 | -6 | 0.01 |
| Covariance, | -53 | 0.04 | -22 | 0.02 | -34 | 0.03 | -16 | 0.01 | -12 | 0.01 |
| Slope variance, | 21 | 0.03 | 14 | 0.02 | 15 | 0.02 | 14 | 0.01 | 15 | 0.01 |
| SE (Treat\*Time),SE () | 0 |  | 1 |  | -2 |  | -4 |  | 5 |  |

%Bias= Percent Relative Bias, RMS=Root Mean Square Error, SE=Standard Error, AR=First-order autoregressive

Table 5. Results From Study Two with an ARH Covariance Structure

|  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- |
|  | 10 (5) | | 10 (15) | | 30 (5) | | 30 (15) | |
|  | %Bias | RMS | %Bias | RMS | %Bias | RMS | %Bias | RMS |
| *Dynamic Group (ARH)* | | | | | | | | |
| Group Time Correlation, | -25 | 0.64 | -4 | 0.29 | -9 | 0.39 | 0 | 0.08 |
| Residual variance, | -4 | 0.06 | 0 | 0.03 | 0 | 0.04 | 0 | 0.02 |
| Intercept variance, | 10 | 0.09 | 3 | 0.05 | 3 | 0.06 | -1 | 0.03 |
| Covariance, | -15 | 0.04 | 0 | 0.02 | 0 | 0.02 | 0 | 0.01 |
| Slope variance, | 6 | 0.03 | 1 | 0.02 | 2 | 0.02 | -1 | 0.01 |
| Group variance Time 1, | 7 | 0.09 | 1 | 0.07 | -3 | 0.06 | -5 | 0.04 |
| Group variance Time 2, | 6 | 0.12 | 2 | 0.08 | -3 | 0.07 | -4 | 0.04 |
| Group variance Time 3, | 2 | 0.14 | -1 | 0.09 | -6 | 0.08 | -5 | 0.05 |
| Group variance Time 4, | 4 | 0.18 | -3 | 0.11 | -6 | 0.11 | -2 | 0.06 |
| SE (Treat\*Time),SE () | -1 |  | -2 |  | -1 |  | 13 |  |
| *Stable Group* |  |  |  |  |  |  |  |  |
| Group variance, | -23 | 0.08 | -27 | 0.07 | -28 | 0.06 | -30 | .05 |
| Residual variance, | 4 | 0.06 | 6 | 0.04 | 5 | 0.04 | 0 | 0.03 |
| Intercept variance, | 5 | 0.08 | -3 | 0.05 | -5 | 0.05 | 6 | 0.03 |
| Covariance, | -47 | 0.04 | -18 | 0.02 | -23 | 0.02 | -8 | 0.03 |
| Slope variance, | 27 | 0.03 | 19 | 0.02 | 21 | 0.02 | -16 | 0.02 |
| SE (Treat\*Time),SE () | 3 |  | 2 |  | 2 |  | 18 |  |

Note: For the 30(15) conditions 100 simulations were evaluate to limit computation time. A 50(50) condition

was not evaluated because proc mixed produced an error of insufficient memory to evaluate the model given the sample size. Hp mixed was not used because it doesn’t contain an ARH option. %Bias for the group variance of the stable group models was based on a parameter value of .13 (average of the variance over the four time periods

Table 6. Results for Simulation Three with a First-Order Autoregressive Population Covariance Structure and 20% Mobility

|  |  |  |  |  |  |  |  |  |  |  |
| --- | --- | --- | --- | --- | --- | --- | --- | --- | --- | --- |
|  | 10 (5) | | 10 (15) | | 30 (5) | | 30 (15) | | 50 (50) | |
|  | %Bias | RMS | %Bias | RMS | %Bias | RMS | %Bias | RMS | %Bias | RMS |
| *Dynamic Group (AR)* | | | | | | | | | | |
| Group variance, | -10 | 0.29 | -5 | 0.15 | -2 | 0.11 | -1 | 0.07 | -1 | 0.04 |
| Residual variance, | -2 | 0.06 | 0 | 0.03 | -1 | 0.03 | 0 | 0.02 | 0 | 0.01 |
| Intercept variance, | 23 | 0.09 | 2 | 0.04 | 4 | 0.05 | -2 | 0.03 | 0 | 0.01 |
| Covariance, | -41 | 0.04 | -6 | 0.02 | -11 | 0.02 | 0 | 0.01 | 0 | 0.01 |
| Slope variance, | 10 | 0.03 | 2 | 0.02 | 4 | 0.02 | 1 | 0.01 | 0 | 0.00 |
| Group Time Correlation | -3 | 0.10 | -1 | 0.08 | 1 | 0.06 | 1 | 0.05 | -1 | 0.03 |
| SE (Treat\*Time),SE () | 5 |  | 1 |  | 1 |  | 4 |  | 1 |  |
| *Stable Group* |  |  |  |  |  |  |  |  |  |  |
| Group variance, | -49 | 0.13 | -39 | 0.10 | -35 | 0.09 | -34 | 0.08 | -36 | 0.08 |
| Residual variance, | 17 | 0.10 | 16 | 0.08 | 16 | 0.08 | 17 | 0.07 | 16 | 0.07 |
| Intercept variance, | 23 | 0.10 | -12 | 0.05 | -1 | 0.06 | -18 | 0.04 | -21 | 0.03 |
| Covariance, | -84 | 0.05 | -10 | 0.02 | -54 | 0.03 | -5 | 0.02 | 11 | 0.01 |
| Slope variance, | 45 | 0.04 | 38 | 0.03 | 44 | 0.03 | 40 | 0.02 | 40 | 0.02 |
| SE (Treat\*Time),SE () | 13 |  | 10 |  | 8 |  | 13 |  | 12 |  |
| *Dynamic Group (AR)* | | | | | | | | | | |
| Group variance, | -24 | 0.47 | -6 | 0.21 | -5 | 0.19 | -2 | 0.08 | 0 | 0.04 |
| Residual variance, | -2 | 0.05 | -1 | 0.03 | -1 | 0.03 | 0 | 0.02 | 0 | 0.01 |
| Intercept variance, | 22 | 0.08 | 5 | 0.05 | 4 | 0.05 | 1 | 0.03 | 0 | 0.01 |
| Covariance, | -32 | 0.04 | -11 | 0.02 | -3 | 0.02 | -1 | 0.01 | 0 | 0.01 |
| Slope variance, | 10 | 0.03 | 5 | 0.02 | 1 | 0.02 | 0 | 0.01 | 0 | 0.00 |
| Group Time Correlation, | 0 | 0.07 | 1 | 0.05 | 1 | 0.04 | -1 | 0.03 | 1 | 0.02 |
| SE (Treat\*Time),SE () | -2 |  | 1 |  | 0 |  | -3 |  | -1 |  |
| *Stable Group* |  |  |  |  |  |  |  |  |  |  |
| Group variance, | -43 | 0.07 | -38 | 0.06 | -37 | 0.05 | -37 | 0.04 | -35 | 0.04 |
| Residual variance, | 8 | 0.07 | 8 | 0.05 | 8 | 0.05 | 8 | 0.04 | 8 | 0.03 |
| Intercept variance, | 18 | 0.08 | 0 | 0.05 | 5 | 0.05 | -4 | 0.03 | -10 | 0.02 |
| Covariance, | -55 | 0.04 | -19 | 0.02 | -34 | 0.02 | -11 | 0.01 | 2 | 0.01 |
| Slope variance, | 26 | 0.03 | 23 | 0.02 | 20 | 0.02 | 20 | 0.01 | 20 | 0.01 |
| SE (Treat\*Time),SE () | 1 |  | 5 |  | 3 |  | 1 |  | 4 |  |